class pantin::backups_minmaxiste_com(
	$ensure = 'present',
	Array[String] $clients,
	$s3_bucket,
	$s3_endpoint,
	Sensitive $s3_access_key_id,
	Sensitive $s3_secret_access_key,
) {
	group { 'rclone':
		system => true,
	} ->
	user { 'rclone':
		gid => 'rclone',
		home => '/run',
		system => true,
	} ->
	file { '/etc/rclone-s3-backups.conf':
		mode => '0640',
		owner => 'root',
		group => 'rclone',
		content => template('pantin/etc/rclone-s3-backups.conf.erb'),
	} ->
	file { '/etc/init.d/rclone-s3-backups':
		mode => '0755',
		content => file('pantin/etc/init.d/rclone-s3-backups'),
	} ->
	service { 'rclone-s3-backups':
		ensure => 'running',
		enable => true,
		subscribe => [
			File['/etc/init.d/rclone-s3-backups'],
			File['/etc/rclone-s3-backups.conf'],
		],
	}

	pantin::apache_http_server::www{ 'backups.ca-east-1.minmaxiste.com':
		ensure => $ensure,
		template => 'backups',
		manage_docroot => false,
		docroot => '/var/www',
		docroot_uid => 'www-data',
		docroot_gid => 'www-data',
		docroot_mode => '0750',
		docroot_options => [ 'Indexes' ],
		docroot_wellknown => false,
	}
}
